home *** CD-ROM | disk | FTP | other *** search
/ Collection of Tools & Utilities / Collection of Tools and Utilities.iso / asmutil / xlt86.zip / XLT86.ASM < prev    next >
Assembly Source File  |  1985-08-15  |  49KB  |  3,181 lines
  1. ;*******************************************************
  2.     page 60,132
  3. ;
  4. ;            XLT86
  5. ;
  6. ; Translates Intel 8080 assembly language source code
  7. ;  to Intel 8086 assembly language source code.
  8. ;
  9. ; 11/11/84 Frank J. Zerilli
  10. ;
  11. ; 8086 version, 11/20/84
  12. ;
  13. ;
  14. ; MS-DOS version 12/20/84
  15. ;  by Craig Derouen
  16.  
  17. VERS    EQU    110
  18. ;
  19. ;*******************************************************
  20. ;
  21. ;      XLT86 processes lines with the exclamation point
  22. ; statement separator correctly.  It strips trailing
  23. ; blanks or tabs from lines.  It replaces initial
  24. ; asterisks in lines with semicolons.  It provides
  25. ; several options to format the output file for best
  26. ; appearance.
  27. ; 
  28. ;      This program gives the choice of converting the
  29. ; case of instructions to upper or lower case or of
  30. ; trying to preserve the case of instructions.
  31. ; 
  32. ;      An activity dot is printed on the console for
  33. ; every 100 lines of input processed.
  34. ; 
  35. ;
  36. ; 
  37. ; Command line:
  38. ;
  39. ;     XLT86 [d:]srcfile[.typ] [d:destfile.typ]
  40. ;
  41. ;      All parameters in brackets are optional, and, if
  42. ; omitted, the default values are:
  43. ;
  44. ;  Source file-type      -- ASM
  45. ;  Destination file-type -- A86
  46. ;  Destination file-name -- same as the source file-name
  47. ;  Drive                 -- current drive
  48. ;
  49. ; FLAG LOCATIONS:
  50. ;
  51. ; 103H -- Change to non-zero value to suppress
  52. ;      translation of several non-standard opcodes:
  53. ;      REQ, RNE, RLT, RGE, CEQ, CNE, CLT, CGE
  54. ;      JEQ, JNE, JLT, JGE,
  55. ;      ENT, NAM, RAM, ROG, IFC, ICL, LST, MAC
  56. ;
  57. ; 104H -- If non-zero (default) XLT86 converts lines
  58. ;      with multiple statements separated by DR's EP
  59. ;      separator into separate lines.
  60. ;      Change to zero for output on a single line
  61. ;      with the translated statements separated by
  62. ;      EP.
  63. ;
  64. ; 107H--  If zero (default) XLT86 translates
  65. ;
  66. ;        PUSH PSW    POP PSW
  67. ;
  68. ;      to
  69. ;
  70. ;        LAHF        POP AX
  71. ;        PUSH AX        SAHF
  72. ;
  73. ;      Otherwise, the translation is
  74. ;
  75. ;        LAHF        POP AX
  76. ;        XCHG AH,AL    XCHG AH,AL
  77. ;        PUSH AX        SAHF
  78. ;        XCHG AH,AL
  79. ;
  80. ; 108H-- If zero (default) XLT86 translates
  81. ;
  82. ;        INX rp        DCX rp
  83. ;
  84. ;     to
  85. ;
  86. ;        INC rp'        DEC rp'
  87. ;
  88. ;     Otherwise, the translation is
  89. ;
  90. ;        PUSHF        PUSHF
  91. ;        INC rp'        DEC rp'
  92. ;        POPF        POPF
  93. ;
  94. ; 109H-- If zero (default) XLT86 translates
  95. ;
  96. ;        DAD rp
  97. ;
  98. ;     to
  99. ;
  100. ;        ADD BX,rp'
  101. ;
  102. ;     Otherwise, the translation is
  103. ;
  104. ;        PUSHF
  105. ;        ADD BX,rp'
  106. ;        POPF
  107. ;
  108.  
  109. N00    EQU    0
  110. N01    EQU    1
  111. ;
  112. N07    EQU    7
  113. N09    EQU    9        ;tab every 8th col.
  114. NF8    EQU    0F8H        ;mod 8
  115. ;
  116. LBUFLN    EQU    80        ;line buffer length
  117. OPBFLN    EQU    5        ;opcode buffer length
  118. MEMSIZ    EQU    4        ;memory available in Kb
  119. IBNUM    EQU    4*MEMSIZ
  120. OBNUM    EQU    4*MEMSIZ
  121. RECLEN    EQU    128        ;
  122. STCKLN    EQU    128        ;stack size
  123. IBFLEN    EQU    IBNUM*RECLEN
  124. OBFLEN    EQU    OBNUM*RECLEN
  125. ;
  126. CTRLC    EQU    3
  127. EOT    EQU    4
  128. BEL    EQU    7
  129. HT    EQU    9
  130. LF    EQU    0AH
  131. CR    EQU    0DH
  132. ESC    EQU    1BH
  133. QUOTE    EQU    27H
  134. ;
  135.  
  136. code    segment byte
  137.  
  138.     assume cs:code,ds:code
  139.  
  140.     ORG    005CH
  141. DFCB1    DB    16 DUP(?)
  142. DFCB2    DB    16 DUP(?)
  143. ;
  144. FNLEN    EQU    8
  145. EOS    EQU    EOT        ; replacement for exclamation pt
  146. EOF    EQU    1AH
  147. NFF    EQU    0FFH        ;disk error return
  148. ;
  149. ;    BDOS FUNCTIONS
  150. ;
  151. nABT    EQU    0
  152. nCIN    EQU    1
  153. nCOUT    EQU    2
  154. nCDAV    EQU    0BH
  155. nOPEN    EQU    0FH
  156. nCLOSE    EQU    10H
  157. nDEL    EQU    13H
  158. nRDNR    EQU    14H
  159. nWRNR    EQU    15H
  160. nCREAT    EQU    16H
  161. nCDISK    EQU    19H
  162. nDMA    EQU    1AH
  163. ;
  164. ;
  165. ;
  166.     ORG    100H
  167. ;
  168. HERE_FIRST:
  169.  
  170.     JMP    START
  171. ;
  172. ; OPTION FLAGS
  173. ;
  174. PSEFLG    DB    0        ;(103H) 0 to translate non-
  175.                 ;  standard opcodes
  176. MLTLFL    DB    0FFH        ;(104H) 0 to put input line with
  177.                 ;  exc. pt. to output on one line
  178. TCASFL    DB    0        ;(105H) 0 to preserve case
  179.                 ;
  180. LCASFL    DB    0        ;(106H) 0 for upper case if
  181.                 ;  TCASFL not zero
  182. PSWFL    DB    0        ;(107H) non-zero to preserve 8080
  183.                 ;  order of PSW registers on stack
  184. INXFL    DB    0        ;(108H) non-zero to preserve flags
  185.                 ;  with INX and DCX translations
  186. DADFL    DB    0        ;(109H) non-zero to preserve flags
  187.                 ;  with DAD translation
  188.                 
  189. ;
  190. ; BDOS Functions
  191. ;
  192. BDOS:
  193.     INT    21H
  194.     RET
  195.  
  196. ;
  197. ; RETURN TO MSDOS
  198. ;
  199. ABORT:    MOV    AH,4ch
  200.     INT    21h
  201.  
  202. ;
  203. ;  HELP MESSAGE
  204. ;
  205. HMSG1:
  206.  
  207.  DB CR,LF
  208.  DB LF
  209.  DB 'XLT86 translates Intel 8080 assembly language source',CR,LF
  210.  DB 'code into Intel 8086 assembly language source code.',CR,LF
  211.  DB LF
  212.  DB 'It is invoked by a command of the form:',CR,LF
  213.  DB LF
  214.  DB '    XLT86 [d:]srcfile[.typ] [d:destfile.typ]',CR,LF
  215.  DB LF
  216.  DB 'The brackets denote optional parameters and the ',CR,LF
  217.  DB 'default values are:',CR,LF
  218.  DB LF
  219.  DB '    Source file-type      --  ASM',CR,LF
  220.  DB '    Destination file-type --  A86',CR,LF
  221.  DB '    Destination file-name --  same as source file-name',CR,LF
  222.  DB '    Drive                 --  current drive',CR,LF
  223.  DB CR,LF
  224.  DB 'Press any key to continue - ',0
  225.  
  226. HMSG2:
  227.  
  228.  DB CR,LF
  229.  DB LF
  230.  DB 'Examples:',CR,LF
  231.  DB LF
  232.  DB 'XLT86 PRGM1               --translates PRGM1.ASM to PRGM1.A86',CR,LF
  233.  DB 'XLT86 PRGM1 PRGM2         --translates PRGM1.ASM to PRGM2.A86',CR,LF
  234.  DB 'XLT86 PRGM1.TXT PRGM2.MAC --translates PRGM1.TXT to PRGM2.MAC',CR,LF
  235.  DB LF
  236.  DB 'XLT86 also has the following features:',CR,LF
  237.  DB LF
  238.  DB 'Case will be preserved as well as possible -- if an opcode has',CR,LF
  239.  DB 'a lower case character, the translated opcode will be in lower',CR,LF
  240.  DB 'case.',CR,LF
  241.  DB LF
  242.  DB 'All asterisks at the beginning of lines will be replaced with',CR,LF
  243.  DB 'semicolons.',CR,LF
  244.  DB LF
  245.  DB 'A dot is printed on the console for every 100 lines of input ',CR,LF
  246.  DB 'processed.',CR,LF
  247.  DB LF
  248.  DB 0
  249. ;
  250. ;=============================================================================
  251. ;
  252. ; Program begins here
  253. ;
  254. START:
  255.     MOV    AX,SS
  256.     MOV    SSBDOS,AX
  257.     MOV    SPBDOS,SP
  258.  
  259.     MOV    AX,CS
  260.     MOV    SS,AX
  261.     MOV    SP,OFFSET STACK
  262.  
  263.     MOV    AL,DFCB1+1    ; check for a file name
  264.     CMP    AL,' '        ; print help if no name
  265.     JNZ    BEGIN        ; no help requested
  266.     MOV    DX,OFFSET SIGNON
  267.     CALL    PRTLIN
  268.     MOV    DX,OFFSET HMSG1    ; print help message
  269.     CALL    PRTLIN
  270.     MOV    AH,nCIN        ; wait for any character
  271.     CALL    BDOS
  272.     MOV    DX,OFFSET HMSG2    ; print rest of help
  273.     CALL    PRTLIN
  274.  
  275.     MOV    AX,SSBDOS
  276.     MOV    SS,AX        ; retrieve system stack
  277.     MOV    SP,SPBDOS    ;  pointer and pop
  278.     MOV    al,2        ; put in an error code
  279.     MOV    AH,4CH
  280.     INT    21H        ; Return to DOS
  281.  
  282. BEGIN:    CALL    HELLO        ;signon, open in & out files
  283. NXTLIN:    CALL    GETLIN        ;get line from input file to buf
  284.     CALL    PROCLIN        ; process line
  285.     JMP    NXTLIN
  286. ;
  287. ;
  288. ;
  289.  
  290. ;*******************************************************
  291. ;
  292. ;    Print signon, open input
  293. ;    and output files.
  294. ;
  295. HELLO:    MOV    DX,OFFSET SIGNON
  296.     CALL    PRTLIN
  297. HELLO0:    MOV    AL,'D'        ; translate DB & EQU (for
  298.     MOV    OPTBDB,AL    ;  uniform formatting)
  299.     MOV    MLTSPC,HT    ; for opcodes xltd to mlt stmts
  300.     MOV    AL,HT        ; HT after opcode
  301.     MOV    BX,OFFSET PUTHT+1
  302.     MOV    [BX],AL
  303.     MOV    AL,41        ; tab comments to col 33
  304.     MOV    BX,OFFSET PUTND5+1
  305.     MOV    [BX],AL
  306.     MOV    AL,3CH        ; CMP instruction
  307.     MOV    BX,OFFSET EXCLAM
  308.     MOV    [BX],AL
  309.     XOR    AL,AL
  310.     MOV    TCASFL,AL    ; don't convert case
  311.     MOV    LCASFL,AL    ; lower case flag
  312.     MOV    SEPMSG,OFFSET NEWLSP
  313.  
  314.     MOV    AL,PSEFLG    ; translate non-standard
  315.     OR    AL,AL        ;  opcodes ?
  316.     JZ    LBL1
  317.      CALL NXPSD
  318. LBL1:
  319.  
  320.     MOV    DX,OFFSET DBMSG
  321.     CALL    PRTLIN        ;
  322.     CALL    CHKYES        ; xlat DB & EQU ?
  323.     CMP    AL,ESC
  324.     JNZ    LBL2
  325.      JMP HELLO0
  326. LBL2:
  327.     CMP    AL,CTRLC
  328.     JNZ    LBL3
  329.      JMP ABORT
  330. LBL3:
  331.     CMP    AL,'Y'
  332.     JZ    LBL4
  333.      CALL NXDBEQ
  334. LBL4:
  335.  
  336.     MOV    AL,MLTLFL    ; force space after opcode
  337.     OR    AL,AL        ;  if MLTLFL not set
  338.     JNZ    LBL5
  339.      JMP HELLO2
  340. LBL5:
  341.     MOV    DX,OFFSET SPCMSG
  342.     CALL    PRTLIN        ; use space after
  343.     CALL    CHKYES        ; opcode ?
  344.     CMP    AL,ESC
  345.     JNZ    LBL6
  346.      JMP HELLO0
  347. LBL6:
  348.     CMP    AL,CTRLC
  349.     JNZ    LBL7
  350.      JMP ABORT
  351. LBL7:
  352.     CMP    AL,'Y'
  353. HELLO2:    JNZ    LBL8
  354.      CALL SETSPC
  355. LBL8:
  356.  
  357.     MOV    DX,OFFSET COLMSG
  358.     CALL    PRTLIN        ;
  359.     CALL    CHKYES        ; start comment
  360.     CMP    AL,ESC
  361.     JNZ    LBL9
  362.      JMP HELLO0
  363. LBL9:
  364.     CMP    AL,CTRLC
  365.     JNZ    LBL10
  366.      JMP ABORT
  367. LBL10:
  368.     CMP    AL,'Y'
  369.     JNZ    LBL11
  370.      CALL SETCOL ; in column 25 ?
  371. LBL11:
  372.  
  373.     MOV    DX,OFFSET EXCMSG
  374.     CALL    PRTLIN        ; Ignore exclamation point
  375.     CALL    CHKYES        ;  separator ?
  376.     CMP    AL,ESC
  377.     JNZ    LBL12
  378.      JMP HELLO0
  379. LBL12:
  380.     CMP    AL,CTRLC
  381.     JNZ    LBL13
  382.      JMP ABORT
  383. LBL13:
  384.     CMP    AL,'Y'
  385.     JNZ    LBL14
  386.      CALL SETNEX
  387. LBL14:
  388.  
  389.     MOV    DX,OFFSET MLTMSG
  390.     CALL    PRTLIN        ; multiple statements
  391.     CALL    CHKYES        ; on one line ?
  392.     CMP    AL,ESC
  393.     JNZ    LBL15
  394.      JMP HELLO0
  395. LBL15:
  396.     CMP    AL,CTRLC
  397.     JNZ    LBL16
  398.      JMP ABORT
  399. LBL16:
  400.     CMP    AL,'Y'
  401.     JNZ    LBL17
  402.      CALL SETMLT
  403. LBL17:
  404.  
  405.